初次提交

第14章 片元着色器的妙用/Sample14_8/assets/frag.sh

@@ -0,0 +1,37 @@
+precision mediump float;
+uniform sampler2D sTexture;//纹理内容数据
+//接收从顶点着色器过来的参数
+varying vec4 ambient;
+varying vec4 diffuse;
+varying vec4 specular;
+varying vec2 vTexPosition;
+const float maxIterations = 99.0;//最大迭代次数
+const float zoom = 0.02;//缩放系数
+const float xCenter = -0.0002;//中心坐标位置
+const float yCenter = 0.7383;
+const vec3 innerColor = vec3(0.0, 0.0, 1.0);//内部颜色
+const vec3 outerColor1 = vec3(1.0, 0.0, 0.0);//外部颜色1
+const vec3 outerColor2 = vec3(0.0, 1.0, 0.0);//外部颜色2
+void main()                         
+{    
+   float real = vTexPosition.x * zoom + xCenter;//变换当前位置
+	float imag = vTexPosition.y * zoom + yCenter;	
+	float cReal = real;//c的实部
+	float cImag = imag;//c的虚部	
+	float r2 = 0.0;//半径的平方
+	float i;//迭代次数  
+	for(i=0.0; i<maxIterations && r2<4.0; i++){//循环迭代
+		float tmpReal = real;//保存当前实部值		
+		real = (tmpReal * tmpReal) - (imag * imag) +cReal;//计算下一次迭代后实部的值
+		imag = 2.0 *tmpReal * imag +cImag;//计算下一次迭代后虚部的值
+		r2 = (real * real) + (imag * imag);//计算半径的平方
+	}
+    vec3 color;    
+    if(r2 < 4.0){//如果r2未达到4就退出了循环，表明迭代次数已达到最大值
+    	color = innerColor;//为内部颜色赋值
+    }else{//如果因r2大于4.0而退出循环，表明此位置在外部
+    	color = mix(outerColor1, outerColor2, fract(i * 0.07));//按迭代次数为外部颜色赋不同的值
+    }    
+    vec4 finalColor=vec4(color, 1.0);
+    gl_FragColor = finalColor*ambient+finalColor*specular+finalColor*diffuse;
+}   

第14章 片元着色器的妙用/Sample14_8/assets/vertex.sh

@@ -0,0 +1,54 @@
+uniform mat4 uMVPMatrix; //总变换矩阵
+uniform mat4 uMMatrix; //变换矩阵
+uniform vec3 uLightLocation;	//光源位置
+uniform vec3 uCamera;	//摄像机位置
+attribute vec3 aPosition;  //顶点位置
+attribute vec3 aNormal;    //顶点法向量
+attribute vec2 aTexCoor;    //顶点纹理坐标
+//用于传递给片元着色器的变量
+varying vec4 ambient;
+varying vec4 diffuse;
+varying vec4 specular;
+varying vec2 vTexPosition;  
+//定位光光照计算的方法
+void pointLight(					//定位光光照计算的方法
+  in vec3 normal,				//法向量
+  inout vec4 ambient,			//环境光最终强度
+  inout vec4 diffuse,				//散射光最终强度
+  inout vec4 specular,			//镜面光最终强度
+  in vec3 lightLocation,			//光源位置
+  in vec4 lightAmbient,			//环境光强度
+  in vec4 lightDiffuse,			//散射光强度
+  in vec4 lightSpecular			//镜面光强度
+){
+  ambient=lightAmbient;			//直接得出环境光的最终强度  
+  vec3 normalTarget=aPosition+normal;	//计算变换后的法向量
+  vec3 newNormal=(uMMatrix*vec4(normalTarget,1)).xyz-(uMMatrix*vec4(aPosition,1)).xyz;
+  newNormal=normalize(newNormal); 	//对法向量规格化
+  //计算从表面点到摄像机的向量
+  vec3 eye= normalize(uCamera-(uMMatrix*vec4(aPosition,1)).xyz);  
+  //计算从表面点到光源位置的向量vp
+  vec3 vp= normalize(lightLocation-(uMMatrix*vec4(aPosition,1)).xyz);  
+  vp=normalize(vp);//格式化vp
+  vec3 halfVector=normalize(vp+eye);	//求视线与光线的半向量    
+  float shininess=50.0;				//粗糙度，越小越光滑
+  float nDotViewPosition=max(0.0,dot(newNormal,vp)); 	//求法向量与vp的点积与0的最大值
+  diffuse=lightDiffuse*nDotViewPosition;				//计算散射光的最终强度
+  float nDotViewHalfVector=dot(newNormal,halfVector);	//法线与半向量的点积 
+  float powerFactor=max(0.0,pow(nDotViewHalfVector,shininess)); 	//镜面反射光强度因子
+  specular=lightSpecular*powerFactor;    			//计算镜面光的最终强度
+}
+
+
+void main()     
+{ 
+   gl_Position = uMVPMatrix * vec4(aPosition,1); //根据总变换矩阵计算此次绘制此顶点位置  
+   
+   vec4 ambientTemp, diffuseTemp, specularTemp;   //存放环境光、散射光、镜面反射光的临时变量      
+   pointLight(normalize(aNormal),ambientTemp,diffuseTemp,specularTemp,uLightLocation,vec4(0.15,0.15,0.15,1.0),vec4(0.9,0.9,0.9,1.0),vec4(0.4,0.4,0.4,1.0));
+   
+   ambient=ambientTemp;
+   diffuse=diffuseTemp;
+   specular=specularTemp;
+   vTexPosition = (aTexCoor-0.5)*5.0;//将接收的纹理坐标传递给片元着色器
+}