初次提交

第15章 真实光学环境的模拟/Sample15_5/assets/frag_tex.sh

@@ -0,0 +1,8 @@
+precision mediump float;
+varying vec2 vTextureCoord; //接收从顶点着色器过来的参数
+uniform sampler2D sTexture;//纹理内容数据
+void main()                         
+{           
+   //给此片元从纹理中采样出颜色值            
+   gl_FragColor = texture2D(sTexture, vTextureCoord); 
+}              

第15章 真实光学环境的模拟/Sample15_5/assets/frag_tex_cube.sh

@@ -0,0 +1,39 @@
+precision mediump float;
+uniform samplerCube sTexture;//纹理内容数据
+varying vec3 eyeVary;		//接收从顶点着色器过来的视线向量
+varying vec3 newNormalVary;	//接收从顶点着色器过来的变换后法向量
+vec4 zfs( //计算折反射纹理采样颜色的方法
+  in float zsl//折射率
+){  
+  vec3 vTextureCoord;	//用于进行立方图纹理采样的向量
+  vec4 finalColorZS;		//若是折射的采样结果
+  vec4 finalColorFS;		//若是反射的采样结果
+  vec4 finalColor;  		//最终颜色
+  const float maxH=0.7;	//入射角余弦值若大于此值则仅计算折射
+  const float minH=0.2;	//入射角余弦值若小于此值则仅计算反射
+  float sizeH=maxH-minH;//混合时余弦值的跨度 
+  float testValue=abs(dot(eyeVary,newNormalVary));	//计算视线向量与法向量的余弦值
+  if(testValue>maxH)  {							//余弦值大于maxH仅折射
+     vTextureCoord=refract(-eyeVary,newNormalVary,zsl);
+     finalColor=textureCube(sTexture, vTextureCoord);  
+  }  else if(testValue<=maxH&&testValue>=minH) {//余弦值在minH～maxH范围内反射、折射融合
+     vTextureCoord=reflect(-eyeVary,newNormalVary);
+     finalColorFS=textureCube(sTexture, vTextureCoord);  	//反射的计算结果
+     vTextureCoord=refract(-eyeVary,newNormalVary,zsl);
+     finalColorZS=textureCube(sTexture, vTextureCoord);  	//折射的计算结果
+     float ratio=(testValue-minH)/sizeH;					//融合比例
+     finalColor=finalColorZS*ratio+(1.0-ratio)*finalColorFS;	//折反射结果线性融合
+  }  else   {										//余弦值小于minH仅反射
+     vTextureCoord=reflect(-eyeVary,newNormalVary);
+     finalColor=textureCube(sTexture, vTextureCoord);  
+  }  
+  return finalColor;									//返回最终结果
+}
+void main(){
+   vec4 finalColor=vec4(0.0,0.0,0.0,0.0);
+   //由于有色散RGB三个色彩通道单独计算折射
+   finalColor.r=zfs(0.97).r;  		//计算红色通道
+   finalColor.g=zfs(0.955).g;  		//计算绿色通道
+   finalColor.b=zfs(0.94).b;  		//计算蓝色通道
+   gl_FragColor=finalColor; 		//将最终的片元颜色传递给管线
+} 

第15章 真实光学环境的模拟/Sample15_5/assets/vertex_tex.sh

@@ -0,0 +1,9 @@
+uniform mat4 uMVPMatrix; //总变换矩阵
+attribute vec3 aPosition;  //顶点位置
+attribute vec2 aTexCoor;    //顶点纹理坐标
+varying vec2 vTextureCoord;  //用于传递给片元着色器的变量
+void main()     
+{                            		
+   gl_Position = uMVPMatrix * vec4(aPosition,1); //根据总变换矩阵计算此次绘制此顶点位置
+   vTextureCoord = aTexCoor;//将接收的纹理坐标传递给片元着色器
+}                      

第15章 真实光学环境的模拟/Sample15_5/assets/vertex_tex_cube.sh

@@ -0,0 +1,18 @@
+uniform mat4 uMVPMatrix; 		//总变换矩阵
+uniform mat4 uMMatrix; 			//变换矩阵
+uniform vec3 uCamera;			//摄像机位置
+attribute vec3 aPosition;  		//顶点位置
+attribute vec3 aNormal;    		//顶点法向量
+varying vec3 eyeVary;			//用于传递给片元着色器的视线向量
+varying vec3 newNormalVary;		//用于传递给片元着色器的变换后法向量
+void main()  { 
+  gl_Position = uMVPMatrix * vec4(aPosition,1); //根据总变换矩阵计算此次绘制此顶点位置    
+   //计算变换后的法向量并规格化
+  vec3 normalTarget=aPosition+aNormal;
+  vec3 newNormal=(uMMatrix*vec4(normalTarget,1)).xyz-(uMMatrix*vec4(aPosition,1)).xyz;
+  newNormal=normalize(newNormal);  
+  newNormalVary=newNormal;//将变换后的法向量传递给片元着色器
+  //计算从观察点到摄像机的向量(视线向量)
+  vec3 eye = normalize(uCamera-(uMMatrix*vec4(aPosition,1)).xyz);
+  eyeVary=eye;//将视线向量传递给片元着色器
+}