apply plugin: 'java-library'
apply plugin: 'maven'

dependencies {
    api project(':vtm-gdx')
    api 'com.github.blackears:svgSalamander:v1.1.1'
}

sourceSets {
    main {
        java.srcDirs = ['src']
    }
}

file('natives').eachDir() { dir ->
    task("nativesJar-${dir.name}", type: Jar) {
        classifier = "natives-${dir.name}"
        from(dir.path)
    }

    artifacts {
        archives tasks["nativesJar-${dir.name}"]
    }
}

if (project.hasProperty("SONATYPE_USERNAME")) {
    afterEvaluate {
        project.apply from: "${rootProject.projectDir}/deploy.gradle"
    }
}
