repositories {
  // libgdx
  maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
}

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'application'

mainClassName = 'org.oscim.gdx.GdxMapApp'

// need to include themes for the example executable
// TODO should be removed someday
task copyAssets(type: Copy) {
  from "${rootDir}/vtm-themes/resources"
  into "${buildDir}"
  include '**/*'
}

// package vtm native libs into jar
task copyLibs(type: Copy) {
  from(zipTree("../vtm-ext-libs/gdx/vtm-jni-natives.jar"))
  into("${buildDir}/assets")
}

tasks.withType(JavaCompile) { compileTask ->
  compileTask.dependsOn copyAssets
  compileTask.dependsOn copyLibs
}

sourceSets {
  main.java.srcDirs = ['src']
  main.resources.srcDirs = ["${buildDir}/assets"]
  output.resourcesDir = 'assets'
}

dependencies {
  compile project(':vtm-gdx')
  compile project(':vtm-themes')
  compile "com.badlogicgames.gdx:gdx-backend-lwjgl:$gdxVersion"
  compile "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
  compile 'org.slf4j:slf4j-simple:1.7.5'
}

eclipse.project {
  linkedResource name: 'assets', type: '2',
		 locationUri: 'PARENT-1-PROJECT_LOC/vtm-themes/resources/assets'
}

run { ignoreExitValue = true }